AC_INIT(configure.in)

AM_CONFIG_HEADER(src/config.h)
AM_INIT_AUTOMAKE(osirion, 0.1)

AC_LANG_CPLUSPLUS
AC_PROG_CXX
AM_PROG_LIBTOOL

dnl KDE_FIND_PATH(programm-name, variable-name, list of directories,
dnl     if-not-found, test-parameter)
AC_DEFUN([KDE_FIND_PATH],
[
   AC_MSG_CHECKING([for $1])
   if test -n "$$2"; then
        kde_cv_path="$$2";
   else
        kde_cache=`echo $1 | sed 'y%./+-%__p_%'`

        AC_CACHE_VAL(kde_cv_path_$kde_cache,
        [
        kde_cv_path="NONE"
        dirs="$3"
        kde_save_IFS=$IFS
        IFS=':'
        for dir in $PATH; do
          dirs="$dirs $dir"
        done
        IFS=$kde_save_IFS

        for dir in $dirs; do
          if test -x "$dir/$1"; then
            if test -n "$5"
            then
              evalstr="$dir/$1 $5 2>&1 "
              if eval $evalstr; then
                kde_cv_path="$dir/$1"
                break
              fi
            else
                kde_cv_path="$dir/$1"
                break
            fi
          fi
        done

        eval "kde_cv_path_$kde_cache=$kde_cv_path"

        ])

      eval "kde_cv_path=\"`echo '$kde_cv_path_'$kde_cache`\""

   fi

   if test -z "$kde_cv_path" || test "$kde_cv_path" = NONE; then
      AC_MSG_RESULT(not found)
      $4
   else
      AC_MSG_RESULT($kde_cv_path)
      $2=$kde_cv_path

   fi
])

AC_MSG_CHECKING([host type])
case "$host" in
        *-*-mingw*)
                HOST_LIBS="-lws2_32"
                HOST_GL_LIBS="-lopengl32 -lglu32"
		ICON_CLIENT="osirion-res.o"
		ICON_SERVER="osiriond-res.o"
                AC_MSG_RESULT(win32)
                ;;
        *)
                HOST_LIBS=""
                HOST_GL_LIBS="-lGL -lGLU"
		ICON_CLIENT=""
		ICON_SERVER=""
                AC_MSG_RESULT(generic unix)
                ;;
esac
AC_SUBST(HOST_LIBS)
AC_SUBST(ICON_CLIENT)
AC_SUBST(ICON_SERVER)

AC_MSG_CHECKING(whether to abort on compiler warnings)
WARN_CFLAGS=""
AC_ARG_ENABLE(warn,
        AC_HELP_STRING(
                [--disable-warn], [don't abort on compiler warnings]
        ),
        AC_MSG_RESULT(no),
        AC_MSG_RESULT(yes)
        WARN_CFLAGS="$WARN_CFLAGS -Wall -Werror"
)
AC_SUBST(WARN_CFLAGS)


AC_MSG_CHECKING(whether to include debug messages)
AC_ARG_ENABLE(debug_messages,
	AC_HELP_STRING(
		[--disable-debug-messages], [build without extra debug information]
	),
	AC_MSG_RESULT(no),
	AC_MSG_RESULT(yes)
	AC_DEFINE_UNQUOTED(HAVE_DEBUG_MESSAGES, 1, [Defines if debug information is enabled])
)

AC_CHECK_HEADER(GL/gl.h,
        HAVE_OPENGL=yes
        AC_DEFINE(HAVE_OPENGL, 1, [Define this if you have OpenGL]),
        HAVE_OPENGL=no
)

AC_CHECK_HEADER(GL/glext.h,
        HAVE_OPENGL_GLEXT=yes
        AC_DEFINE(HAVE_OPENGL_GLEXT, 1, [Define this if you have OpenGL Extensions]),
        HAVE_OPENGL_GLEXT=no,
        [#include <GL/gl.h>]
)


GL_LIBS="$HOST_GL_LIBS"

AC_SUBST(GL_LIBS)
AC_SUBST(GL_CFLAGS)

AC_MSG_CHECKING([looking for SDL])
KDE_FIND_PATH(sdl-config, LIBSDL_CONFIG, [${prefix}/bin ${exec_prefix}/bin /usr/local/bin /opt/local/bin], [
  AC_MSG_WARN([Could not find libSDL, check http://www.sdl.org])
])

if test -n "$LIBSDL_CONFIG"; then
     LIBSDL_LIBS="`$LIBSDL_CONFIG --libs`"
     LIBSDL_RPATH=
     for args in $LIBSDL_LIBS; do
          case $args in
            -L*)
               LIBSDL_RPATH="$LIBSDL_RPATH $args"
               ;;
          esac
     done
     LIBSDL_RPATH=`echo $LIBSDL_RPATH | sed -e "s/-L/-R/g"`
     LIBSDL_CFLAGS="`$LIBSDL_CONFIG --cflags`"

     AC_DEFINE_UNQUOTED(HAVE_LIBSDL, 1, [Defines if your system has the LIBSDL library])
fi

AC_MSG_RESULT($HAVE_LIBSDL)

AC_SUBST(LIBSDL_LIBS)
AC_SUBST(LIBSDL_CFLAGS)
AC_SUBST(LIBSDL_RPATH)

CXXFLAGS="-pipe $DEBUG_CFLAGS $WARN_CFLAGS $CXXFLAGS"
AC_SUBST(CXXFLAGS)

dnl ---------------------------------------------------------------
dnl   Installation paths

test "$prefix" = "NONE" && prefix="/opt/games/$PACKAGE"

PACKAGE_PREFIX="$prefix"
PACKAGE_BINDIR="$prefix/bin"
PACKAGE_DATADIR="$prefix/data"
PACKAGE_LIBDIR="$prefix/lib"

AC_DEFINE_UNQUOTED(PACKAGE_PREFIX, "$PACKAGE_PREFIX",
	[Define this to the path where the game will be installed.]
)

AC_DEFINE_UNQUOTED(PACKAGE_BINDIR, "$PACKAGE_BINDIR",
	[Define this to the path containing the game binaries.]
)

AC_DEFINE_UNQUOTED(PACKAGE_DATADIR, "$PACKAGE_DATADIR",
	[Define this to the path containing the game data.]
)

AC_DEFINE_UNQUOTED(PACKAGE_LIBDIR, "$PACKAGE_LIBDIR",
	[Define this to the path containing the game libraries.]
)

dnl ---------------------------------------------------------------
dnl    Write makefiles and config.h

AC_OUTPUT(Makefile src/Makefile src/client/Makefile src/core/Makefile \
	src/filesystem/Makefile src/game/Makefile src/math/Makefile src/render/Makefile src/server/Makefile \
	src/sys/Makefile)

dnl ---------------------------------------------------------------
dnl   Configuration summary

AC_MSG_RESULT([
The Osirion Project $VERSION

Configuration summary:
	platform ........... $host
	flags .............. $CXXFLAGS
	libraries .......... $HOST_LIBS
	opengl ............. $GL_LIBS

Installation directories:
	prefix ............. $PACKAGE_PREFIX
	binaries ........... $PACKAGE_BINDIR
	libraries .......... $PACKAGE_LIBDIR
	data ............... $PACKAGE_DATADIR
])